QLab列表创建音频淡入淡出

在QLab中编程节目时，最重复的任务之一就是创建淡入淡出。您启动的每个音频Cue在某个时候都可能需要淡入淡出，很遗憾的是QLab软件并没有傻瓜式的自动过渡功能，虽然可以设置独奏模式在切换Cue的时候淡出正在播放的Cue，但这个功能只适合网格Cart模式，并不适合剧场列表模式。因此你只能手动的给需要淡入淡出的Cue添加Fade Cue。这个工作很繁琐，在此我们提供了一个基于AppleScript脚本的方法，可以快速为音频Cue创建淡入和淡出。

首先，我们先看一下QLab常规的两种淡入淡出编程样式，这两种方法的起点是相同的：将立体声音频文件拖到Cue列表中以创建音频Cue。当我们要在某个时候淡入或淡出音乐，则在音频Cue后面创建一个淡入或淡出Fade。

淡出：

淡出很容易理解，就是在一个音频正在播放的时候把音量推子拉到无声位置。那么只需要添加一个Fade 设置音量到-INF即可。操作如下：

1. 选择音频Cue；
2. 通过点击工具栏中的“Fade” 图标或使用键盘快捷键⌘+7（4.4以后的版本快捷键是⌘+5）在当前Cue的下方创建一个Fade Cue。
   注意：如果您使用的是QLab 4.4或更高版本，则“Fade”Cue将自动把目标设置为所选定的音频Cue。如果是QLab的早期版本，则需要在新建的Fade Cue上面手动设置Fade Cue的目标编号。
3. 在Audio Levels选项晨将Fade Cue的主音量设置为-INF 并单击完成后停止目标（也就是淡出后结束音乐，除非你只是让它暂时淡出音量而不是结束音乐。）
4. 在Curve Shape检查器里设置Fade的“曲线形状”和Fade的持续时间(也就是需要淡入或淡出的时间)。

淡入：

作为音响师我们知道调音台的淡入就是推子由无声音往上推到0db位置(别问我为什么是0)，所以QLab淡入Fade的前提条件是需要将原始音频Cue的音量设置为无声也就是-INF，然后淡入的Fade Cue将目标音量设置为0，并且启动原始音频的同时勾上“Auto continue”，也就是播放音乐的时候同时启动淡入Cue。

1. 选择音频Cue；
2. 通过点击工具栏中的“Fade” 图标或使用键盘快捷键⌘+7（4.4以后的版本快捷键是⌘+5）在当前Cue的下方创建一个Fade Cue。
   注意：如果您使用的是QLab 4.4或更高版本，则“Fade”Cue将自动把目标设置为所选定的音频Cue。如果是QLab的早期版本，则需要在新建的Fade Cue上面手动设置Fade Cue的目标编号。
3. 将原始音频Cue的主音量设置为-INF
4. 按空格键或点击GO按钮启动音频Cue;
5. 确保“ Live Fade Preview”处于打开状态（位于“ Fade Cue”的Audio Levels选项里），并将Fade Cue的主音量调整为所需的级别
6. 在Curve Shape检查器里设置Fade的“曲线形状”和Fade的持续时间(也就是需要淡入或淡出的时间)。

以上就是QLab最基本的音频淡出及淡入的Fade设置，如果你需要切换音乐的时候淡出及淡入，就需要在运行下一个音频的时候同时启动两个Fade Cue。

简单的理解就是同时启动3个Cue（1.音频本身, 2.淡入音频. 3.淡出上一个音频）如果按照列表的方式进行设置会很乱，这时我们可以使用编组的方式进行。就是把这3个Cue放在一个编组里，并设置这个编组的运行模式是：同时启动编组里所有Cue 这样只要运行这个编组就会执行：启动音频,淡入音频和淡出上一个音频的操作。

看到这里很多人会说：这么复杂还不如用酷狗 QQ播放器来的方便。的确！对于一般的演出场合或街头路演之类的酷狗之类的傻瓜式播放器更简单直接。但对于一些大型演出或剧场,小品,话剧之类对音频的精准插入有严格要求的场合QLab才是利器。别忘了它还可以设置前等待时间，以及在列表里添加各种开始,暂停,恢复Cue等操作，这些都可以为你的演出自动化提供强大支持。如果什么都是傻瓜式操作，那还谈什么专业演出？

到此我们就知道了怎么创建淡出和淡入的设置，如果你需要每次切换音乐都要执行淡出淡入，就需要反复的复制粘贴上面的操作，并且还要修改每个Fade Cue的目标和反复的添加编组。这个的确很繁琐并且浪费不少时间。

好在QLab提供了强大的脚本Cue，通过AppleScript我们可以使用脚本对这个复制粘贴的操作进行自动化。具体的操作就是：当我们选择一个音频的时候，运行脚本Cue 它会自动创建一个编组并且添加一个淡入及淡出的Fade Cue，并且会自动设置目标为所选的音频。

set inDuration to 5 --设置淡入时间
set outDuration to 10 --设置淡出时间
set minVolume to -60 -- 设置最低音量
tell application id "com.figure53.QLab.4" to tell front workspace
	try
		set audioCue to last item of (selected as list)
		set q number of audioCue to ""
		if q type of audioCue is "Audio" then
			make type "Fade"
			set fadeOutCue to last item of (selected as list)
			set the q number of fadeOutCue to ""
			set cue target of fadeOutCue to audioCue
			set duration of fadeOutCue to outDuration
			fadeOutCue setLevel row 0 column 0 db minVolume
			set stop target when done of fadeOutCue to true
			set q name of fadeOutCue to "Fade out  " & q list name of audioCue & " (" & outDuration & "s)"
			set audioCueLevel to audioCue getLevel row 0 column 0
			fadeOutCue setLevel row 0 column 0 db minVolume
			moveSelectionUp
			make type "Fade"
			set fadeCue to last item of (selected as list)
			set q number of fadeCue to ""
			set cue target of fadeCue to audioCue
			set duration of fadeCue to inDuration
			fadeCue setLevel row 0 column 0 db audioCueLevel
			audioCue setLevel row 0 column 0 db minVolume
			set cuesToGroup to {audioCue, fadeCue}
			make type "Group"
			set groupCue to last item of (selected as list)
			set mode of groupCue to fire_all
			set q name of groupCue to "Fade in " & q list name of audioCue & " (" & inDuration & "s)"
			repeat with eachCue in cuesToGroup
				set eachCueID to uniqueID of eachCue
				move cue id eachCueID of parent of eachCue to end of groupCue
			end repeat
		end if
	end try
end tell

以上是脚本Cue的AppleScript代码，你只需要复制到脚本Cue里面的代码区，然后给脚本Cue设置的一个快捷键，这样当你需要给某个音频添加淡入淡出Fade的时候 按下快捷键，它就会自动创建淡入淡出。AppleScript代码前两行分别是淡入和淡出的时间设置。以下是视频演示：

你也可以直接下载这个工程文件直接添加音频操作即可

Swain永久会员

收藏 海报 链接